如何使用 TSQL 检查数据库的 SQLServer 版本？

是否有系统存储过程来获取版本 # ？

237483 次浏览
小开

选择@@ 版本

小开
最佳答案

试试看

SELECT @@VERSION

或对于 SQLServer2000及以上版本，以下内容更容易解析:)

SELECT SERVERPROPERTY('productversion')
, SERVERPROPERTY('productlevel')
, SERVERPROPERTY('edition')

发信人: http://support.microsoft.com/kb/321185

小开

乔的岗位中链接的知识库文章对于确定已经为任何版本安装了哪些服务包非常有用。沿着同样的路线，这篇 KB 文章将版本号映射到特定的修复程序和累积更新，但它只适用于 SQL05SP2及以上版本。

小开

下面是我用来测试服务器是否是2005或更高版本的一些脚本

declare @isSqlServer2005 bit
select @isSqlServer2005 = case when CONVERT(int, SUBSTRING(CONVERT(varchar(15), SERVERPROPERTY('productversion')), 0, CHARINDEX('.', CONVERT(varchar(15), SERVERPROPERTY('productversion'))))) < 9 then 0 else 1 end
select @isSqlServer2005

注: 从原来的答案更新(见评论)

小开

试试这个:

if (SELECT LEFT(CAST(SERVERPROPERTY('productversion') as varchar), 2)) = '10'
BEGIN
小开

对于 SQLServer2000及以上版本，我更喜欢对 Joe 的答案进行以下解析:

declare @sqlVers numeric(4,2)
select @sqlVers = left(cast(serverproperty('productversion') as varchar), 4)

结果如下:

Result   Server Version
8.00     SQL 2000
9.00     SQL 2005
10.00    SQL 2008
10.50    SQL 2008R2
11.00    SQL 2012
12.00    SQL 2014

版本号 给你的基本列表，或 Microsoft给你的详尽列表。

小开

我知道这是一个较老的职位，但我更新的代码发现在 链接(已死亡的2013年12月03日)提到的 回答由 马特 · 罗吉什发布:

DECLARE @ver nvarchar(128)
SET @ver = CAST(serverproperty('ProductVersion') AS nvarchar)
SET @ver = SUBSTRING(@ver, 1, CHARINDEX('.', @ver) - 1)


IF ( @ver = '7' )
SELECT 'SQL Server 7'
ELSE IF ( @ver = '8' )
SELECT 'SQL Server 2000'
ELSE IF ( @ver = '9' )
SELECT 'SQL Server 2005'
ELSE IF ( @ver = '10' )
SELECT 'SQL Server 2008/2008 R2'
ELSE IF ( @ver = '11' )
SELECT 'SQL Server 2012'
ELSE IF ( @ver = '12' )
SELECT 'SQL Server 2014'
ELSE IF ( @ver = '13' )
SELECT 'SQL Server 2016'
ELSE IF ( @ver = '14' )
SELECT 'SQL Server 2017'
ELSE
SELECT 'Unsupported SQL Server Version'
小开 
SELECT
@@SERVERNAME AS ServerName,
CASE WHEN LEFT(CAST(serverproperty('productversion') as char), 1) = 9 THEN '2005'
WHEN LEFT(CAST(serverproperty('productversion') as char), 2) = 10 THEN '2008'
WHEN LEFT(CAST(serverproperty('productversion') as char), 2) = 11 THEN '2012'
END AS MajorVersion,
SERVERPROPERTY ('productlevel') AS MinorVersion,
SERVERPROPERTY('productversion') AS FullVersion,
SERVERPROPERTY ('edition') AS Edition
小开

仅在单个选择中获取主要 SQLServer 版本:

SELECT  SUBSTRING(ver, 1, CHARINDEX('.', ver) - 1)
FROM (SELECT CAST(serverproperty('ProductVersion') AS nvarchar) ver) as t

返回用于 SQL2000的 8，用于 SQL2005的 9等等(直到2012年测试)。

小开

还有另一个扩展存储过程，可用于查看版本信息:

exec [master].sys.[xp_msver]
小开 
CREATE FUNCTION dbo.UFN_GET_SQL_SEVER_VERSION
(
)
RETURNS sysname
AS
BEGIN
DECLARE @ServerVersion sysname, @ProductVersion sysname, @ProductLevel sysname, @Edition sysname;


SELECT @ProductVersion = CONVERT(sysname, SERVERPROPERTY('ProductVersion')),
@ProductLevel = CONVERT(sysname, SERVERPROPERTY('ProductLevel')),
@Edition = CONVERT(sysname, SERVERPROPERTY ('Edition'));
--see: http://support2.microsoft.com/kb/321185
SELECT @ServerVersion =
CASE
WHEN @ProductVersion LIKE '8.00.%' THEN 'Microsoft SQL Server 2000'
WHEN @ProductVersion LIKE '9.00.%' THEN 'Microsoft SQL Server 2005'
WHEN @ProductVersion LIKE '10.00.%' THEN 'Microsoft SQL Server 2008'
WHEN @ProductVersion LIKE '10.50.%' THEN 'Microsoft SQL Server 2008 R2'
WHEN @ProductVersion LIKE '11.0%' THEN 'Microsoft SQL Server 2012'
WHEN @ProductVersion LIKE '12.0%' THEN 'Microsoft SQL Server 2014'
END


RETURN @ServerVersion + N' ('+@ProductLevel + N'), ' + @Edition + ' - ' + @ProductVersion;


END
GO
小开

试试这个:

SELECT
'the sqlserver is ' + substring(@@VERSION, 21, 5) AS [sql version]
小开

如果由于 T-SQL 的原因，您需要的只是主版本，那么下面提供的是2000年或更高版本的 SQLServer 版本年份。

SELECT left(ltrim(replace(@@Version,'Microsoft SQL Server','')),4)

此代码可以很好地处理各种版本的 SQLServer 的额外空格和制表符。

小开

试试这个:

SELECT @@VERSION[server], SERVERPROPERTY('productversion'), SERVERPROPERTY ('productlevel'), SERVERPROPERTY ('edition')
小开

试试看

SELECT @@MICROSOFTVERSION / 0x01000000 AS MajorVersionNumber

有关更多信息，请参见: 查询版本/版本信息

小开 
select substring(@@version,0,charindex(convert(varchar,SERVERPROPERTY('productversion')) ,@@version)+len(convert(varchar,SERVERPROPERTY('productversion'))))

提交答案