有没有办法使 TSQL 变量常数？

There are no such thing as "creating a constant" in database literature. Constants exist as they are and often called values. One can declare a variable and assign a value (constant) to it. From a scholastic view:

DECLARE @two INT
SET @two = 2

Here @two is a variable and 2 is a value/constant.

No, but you can create a function and hardcode it in there and use that.

Here is an example:

CREATE FUNCTION fnConstant()
RETURNS INT
AS
BEGIN
RETURN 2
END
GO


SELECT dbo.fnConstant()

No, but good old naming conventions should be used.

declare @MY_VALUE as int

Okay, lets see

Constants are immutable values which are known at compile time and do not change for the life of the program

that means you can never have a constant in SQL Server

declare @myvalue as int
set @myvalue = 5
set @myvalue = 10--oops we just changed it

the value just changed

There is no built-in support for constants in T-SQL. You could use SQLMenace's approach to simulate it (though you can never be sure whether someone else has overwritten the function to return something else…), or possibly write a table containing constants, as suggested over here. Perhaps write a trigger that rolls back any changes to the ConstantValue column?

My workaround to missing constans is to give hints about the value to the optimizer.

DECLARE @Constant INT = 123;


SELECT *
FROM [some_relation]
WHERE [some_attribute] = @Constant
OPTION( OPTIMIZE FOR (@Constant = 123))

This tells the query compiler to treat the variable as if it was a constant when creating the execution plan. The down side is that you have to define the value twice.

The best answer is from SQLMenace according to the requirement if that is to create a temporary constant for use within scripts, i.e. across multiple GO statements/batches.

Just create the procedure in the tempdb then you have no impact on the target database.

One practical example of this is a database create script which writes a control value at the end of the script containing the logical schema version. At the top of the file are some comments with change history etc... But in practice most developers will forget to scroll down and update the schema version at the bottom of the file.

Using the above code allows a visible schema version constant to be defined at the top before the database script (copied from the generate scripts feature of SSMS) creates the database but used at the end. This is right in the face of the developer next to the change history and other comments, so they are very likely to update it.

For example:

use tempdb
go
create function dbo.MySchemaVersion()
returns int
as
begin
return 123
end
go


use master
go


-- Big long database create script with multiple batches...
print 'Creating database schema version ' + CAST(tempdb.dbo.MySchemaVersion() as NVARCHAR) + '...'
go
-- ...
go
-- ...
go
use MyDatabase
go


-- Update schema version with constant at end (not normally possible as GO puts
-- local @variables out of scope)
insert MyConfigTable values ('SchemaVersion', tempdb.dbo.MySchemaVersion())
go


-- Clean-up
use tempdb
drop function MySchemaVersion
go

Prior to using a SQL function run the following script to see the differences in performance:

IF OBJECT_ID('fnFalse') IS NOT NULL
DROP FUNCTION fnFalse
GO


IF OBJECT_ID('fnTrue') IS NOT NULL
DROP FUNCTION fnTrue
GO


CREATE FUNCTION fnTrue() RETURNS INT WITH SCHEMABINDING
AS
BEGIN
RETURN 1
END
GO


CREATE FUNCTION fnFalse() RETURNS INT WITH SCHEMABINDING
AS
BEGIN
RETURN ~ dbo.fnTrue()
END
GO


DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000
WHILE @Count > 0 BEGIN
SET @Count -= 1


DECLARE @Value BIT
SELECT @Value = dbo.fnTrue()
IF @Value = 1
SELECT @Value = dbo.fnFalse()
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using function'
GO


DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000
DECLARE @FALSE AS BIT = 0
DECLARE @TRUE AS BIT = ~ @FALSE


WHILE @Count > 0 BEGIN
SET @Count -= 1


DECLARE @Value BIT
SELECT @Value = @TRUE
IF @Value = 1
SELECT @Value = @FALSE
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using local variable'
GO


DECLARE @TimeStart DATETIME = GETDATE()
DECLARE @Count INT = 100000


WHILE @Count > 0 BEGIN
SET @Count -= 1


DECLARE @Value BIT
SELECT @Value = 1
IF @Value = 1
SELECT @Value = 0
END
DECLARE @TimeEnd DATETIME = GETDATE()
PRINT CAST(DATEDIFF(ms, @TimeStart, @TimeEnd) AS VARCHAR) + ' elapsed, using hard coded values'
GO

One solution, offered by Jared Ko is to use pseudo-constants.

As explained in SQL Server: Variables, Parameters or Literals? Or… Constants?:

Pseudo-Constants are not variables or parameters. Instead, they're simply views with one row, and enough columns to support your constants. With these simple rules, the SQL Engine completely ignores the value of the view but still builds an execution plan based on its value. The execution plan doesn't even show a join to the view!

Create like this:

CREATE SCHEMA ShipMethod
GO
-- Each view can only have one row.
-- Create one column for each desired constant.
-- Each column is restricted to a single value.
CREATE VIEW ShipMethod.ShipMethodID AS
SELECT CAST(1 AS INT) AS [XRQ - TRUCK GROUND]
,CAST(2 AS INT) AS [ZY - EXPRESS]
,CAST(3 AS INT) AS [OVERSEAS - DELUXE]
,CAST(4 AS INT) AS [OVERNIGHT J-FAST]
,CAST(5 AS INT) AS [CARGO TRANSPORT 5]

Then use like this:

SELECT h.*
FROM Sales.SalesOrderHeader h
JOIN ShipMethod.ShipMethodID const
ON h.ShipMethodID = const.[OVERNIGHT J-FAST]

Or like this:

SELECT h.*
FROM Sales.SalesOrderHeader h
WHERE h.ShipMethodID = (SELECT TOP 1 [OVERNIGHT J-FAST] FROM ShipMethod.ShipMethodID)

If you are interested in getting optimal execution plan for a value in the variable you can use a dynamic sql code. It makes the variable constant.

DECLARE @var varchar(100) = 'some text'
DECLARE @sql varchar(MAX)
SET @sql = 'SELECT * FROM table WHERE col = '''+@var+''''
EXEC (@sql)

For enums or simple constants, a view with a single row has great performance and compile time checking / dependency tracking ( cause its a column name )

See Jared Ko's blog post https://blogs.msdn.microsoft.com/sql_server_appendix_z/2013/09/16/sql-server-variables-parameters-or-literals-or-constants/

create the view

 CREATE VIEW ShipMethods AS
SELECT CAST(1 AS INT) AS [XRQ - TRUCK GROUND]
,CAST(2 AS INT) AS [ZY - EXPRESS]
,CAST(3 AS INT) AS [OVERSEAS - DELUXE]
, CAST(4 AS INT) AS [OVERNIGHT J-FAST]
,CAST(5 AS INT) AS [CARGO TRANSPORT 5]

use the view

SELECT h.*
FROM Sales.SalesOrderHeader
WHERE ShipMethodID = ( select [OVERNIGHT J-FAST] from ShipMethods  )

Since there is no build in support for constants, my solution is very simple.

Since this is not supported:

Declare Constant @supplement int = 240
SELECT price + @supplement
FROM   what_does_it_cost

I would simply convert it to

SELECT price + 240/*CONSTANT:supplement*/
FROM   what_does_it_cost

Obviously, this relies on the whole thing (the value without trailing space and the comment) to be unique. Changing it is possible with a global search and replace.

SQLServer 2022 (currently only as Preview available) is now able to Inline the function proposed by SQLMenace, this should prevent the performance hit described by some comments.

CREATE FUNCTION fnConstant() RETURNS INT AS BEGIN RETURN 2 END GO

SELECT is_inlineable FROM sys.sql_modules WHERE [object_id]=OBJECT_ID('dbo.fnConstant');

SELECT dbo.fnConstant()

ExecutionPlan

To test if it also uses the value coming from the Function, I added a second function returning value "1"

CREATE FUNCTION fnConstant1()
RETURNS INT
AS
BEGIN
RETURN 1
END
GO

Create Temp Table with about 500k rows with Value 1 and 4 rows with Value 2:

DROP TABLE IF EXISTS #temp ;
create table #temp (value_int INT)
DECLARE @counter INT;
SET @counter = 0
WHILE @counter <= 500000
BEGIN
INSERT INTO #temp VALUES (1);
SET @counter = @counter +1
END
SET @counter = 0
  

WHILE @counter <= 3
BEGIN
INSERT INTO #temp VALUES (2);
SET @counter = @counter +1
END
create index i_temp on #temp (value_int);

Using the describe plan we can see that the Optimizer expects 500k values for
select * from #temp where value_int = dbo.fnConstant1(); --Returns 500001 rows Constant 1

and 4 rows for
select * from #temp where value_int = dbo.fnConstant(); --Returns 4rows
Constant 2

Robert's performance test is interesting. And even in late 2022, the scalar functions are much slower (by an order of magnitude) than variables or literals. A view (as suggested mbobka) is somewhere in-between when used for this same test.

That said, using a loop like that in SQL Server is not something I'd ever do, because I'd normally be operating on a whole set.

In SQL 2019, if you use schema-bound functions in a set operation, the difference is much less noticeable.

I created and populated a test table:

create table #testTable (id int identity(1, 1) primary key, value tinyint);

And changed the test so that instead of looping and changing a variable, it queries the test table and returns true or false depending on the value in the test table, e.g.:

insert @testTable(value)
select case when value > 127
then @FALSE
else @TRUE
end
from #testTable with(nolock)

I tested 5 scenarios:

1. hard-coded values
2. local variables
3. scalar functions
4. a view
5. a table-valued function

running the test 10 times, yielded the following results:

Suggesting to me, that for set-based work in (at least) 2019 and better, there's not much in it.

set nocount on;
go


-- create test data table
drop table if exists #testTable;
create table #testTable (id int identity(1, 1) primary key, value tinyint);


-- populate test data
insert #testTable (value)
select top (1000000) convert(binary (1), newid())
from sys.all_objects a
, sys.all_objects b
go


-- scalar function for True
drop function if exists fnTrue;
go
create function dbo.fnTrue() returns bit with schemabinding as
begin
return 1
end
go


-- scalar function for False
drop function if exists fnFalse;
go
create function dbo.fnFalse () returns bit with schemabinding as
begin
return 0
end
go


-- table-valued function for booleans
drop function if exists dbo.tvfBoolean;
go
create function tvfBoolean() returns table with schemabinding as
return
select convert(bit, 1) as true, convert(bit, 0) as false
go


-- view for booleans
drop view if exists dbo.viewBoolean;
go
create view dbo.viewBoolean with schemabinding as
select convert(bit, 1) as true, convert(bit, 0) as false
go


-- create table for results
drop table if exists #testResults
create table #testResults (id int identity(1,1), test int, elapsed bigint, message varchar(1000));


-- define tests
declare @tests table(testNumber int, description nvarchar(100), sql nvarchar(max))
insert @tests values
(1, N'hard-coded values', N'
declare @testTable table (id int, value bit);
insert @testTable(id, value)
select id, case when t.value > 127
then 0
else 1
end
from #testTable t')
, (2, N'local variables', N'
declare @FALSE as bit = 0
declare @TRUE as bit = 1
declare @testTable table (id int, value bit);
insert @testTable(id, value)
select id, case when t.value > 127
then @FALSE
else @TRUE
end
from #testTable t'),
(3, N'scalar functions', N'
declare @testTable table (id int, value bit);
insert @testTable(id, value)
select id, case when t.value > 127
then dbo.fnFalse()
else dbo.fnTrue()
end
from #testTable t'),
(4, N'view', N'
declare @testTable table (id int, value bit);
insert @testTable(id, value)
select id, case when value > 127
then b.false
else b.true
end
from #testTable t with(nolock), viewBoolean b'),
(5, N'table-valued function', N'
declare @testTable table (id int, value bit);
insert @testTable(id, value)
select id, case when value > 127
then b.false
else b.true
end
from #testTable with(nolock), dbo.tvfBoolean() b')
;


declare @testNumber int, @description varchar(100), @sql nvarchar(max)


declare @testRuns int = 10;


-- execute tests
while @testRuns > 0 begin
set @testRuns -= 1


declare testCursor cursor for select testNumber, description, sql from @tests;
open testCursor


fetch next from testCursor into @testNumber, @description, @sql
while @@FETCH_STATUS = 0 begin
        

declare @TimeStart datetime2(7) = sysdatetime();


execute sp_executesql @sql;


declare @TimeEnd datetime2(7) = sysdatetime()


insert #testResults(test, elapsed, message)
select @testNumber, datediff_big(ms, @TimeStart, @TimeEnd), @description


fetch next from testCursor into @testNumber, @description, @sql
end
close testCursor
deallocate testCursor
end




-- display results
select test, message, count(*) runs, min(elapsed) as min, max(elapsed) as max, avg(elapsed) as avg
from #testResults
group by test, message
order by avg(elapsed);