最简单但是最完整的 CMake 例子

不知为何，我完全搞不懂 CMake 是如何工作的。每当我认为我越来越接近理解 CMake 应该是如何编写的时候，它就在我读到的下一个例子中消失了。我想知道的是，我应该如何构建我的项目，以便我的 CMake 在未来需要最少的维护。例如，当我在 src 树中添加一个新文件夹时，我不想更新 CMakeList.txt，因为它的工作原理与所有其他 src 文件夹完全一样。

这是我如何想象我的项目的结构，但请这只是一个例子。如果推荐的方法不同，请告诉我，并告诉我如何做到这一点。

myProject
src/
module1/
module1.h
module1.cpp
module2/
[...]
main.cpp
test/
test1.cpp
resources/
file.png
bin
[execute cmake ..]

顺便说一句，我的程序必须知道资源在哪里。我想知道管理资源的推荐方法。我不想访问我的资源”。./resources/file. png”

106176 次浏览
小开

最基本但最完整的例子可以在 制作教程中找到:

cmake_minimum_required (VERSION 2.6)
project (Tutorial)
add_executable(Tutorial tutorial.cxx)

对于你的项目例子，你可能有:

cmake_minimum_required (VERSION 2.6)
project (MyProject)
add_executable(myexec src/module1/module1.cpp src/module2/module2.cpp src/main.cpp)
add_executable(mytest test1.cpp)

对于您的附加问题，教程中还有一个方法: 创建一个可配置的头文件，并将其包含在代码中。为此，创建一个包含以下内容的文件 configuration.h.in:

#define RESOURCES_PATH "@RESOURCES_PATH@"

然后在你的 CMakeLists.txt中添加:

set(RESOURCES_PATH "${PROJECT_SOURCE_DIR}/resources/")
# configure a header file to pass some of the CMake settings
# to the source code
configure_file (
"${PROJECT_SOURCE_DIR}/configuration.h.in"
"${PROJECT_BINARY_DIR}/configuration.h"
)


# add the binary tree to the search path for include files
# so that we will find TutorialConfig.h
include_directories("${PROJECT_BINARY_DIR}")

最后，在需要代码中的路径时，可以这样做:

#include "configuration.h"


...


string resourcePath = string(RESOURCE_PATH) + "file.png";
小开
最佳答案

经过一些研究，我现在有了自己版本的最简单但是最完整的 CMake 示例。在这里，它试图涵盖大多数基础知识，包括资源和打包。

它所做的一件非标准的事情是资源处理。默认情况下，CMake 希望将它们放在 [ usr/share ]、 /usr/local/share/以及 Windows 上的一些等价物中。我希望有一个简单的 zip/tar.gz 文件，您可以在任何地方解压缩并运行它。因此，资源是相对于可执行文件加载的。

理解 CMake 命令的基本规则是以下语法: 没有逗号或分号的 <function-name>(<arg1> [<arg2> ...])。每个参数都是一个字符串。foobar(3.0)和 foobar("3.0")是一样的。您可以使用 set(args arg1 arg2)设置列表/变量。与这个变量集 foobar(${args})和 foobar(arg1 arg2)实际上是相同的。一个不存在的变量等价于一个空列表。列表在内部只是一个带分号的字符串，用于分隔元素。因此，根据定义，只有一个元素的列表就只是那个元素，不会进行装箱。

变量是全局的。内置函数提供某种形式的 命名论点，因为它们希望参数列表中的某些 id (如 PUBLIC或 DESTINATION)对参数进行分组。但这不是一个语言特性; 这些 id 也只是字符串，由函数实现解析。

你可以克隆所有的 来自 GitHub。

cmake_minimum_required(VERSION 3.0)
project(example_project)


###############################################################################
## file globbing ##############################################################
###############################################################################


# these instructions search the directory tree when CMake is
# invoked and put all files that match the pattern in the variables
# `sources` and `data`
file(GLOB_RECURSE sources      src/main/*.cpp src/main/*.h)
file(GLOB_RECURSE sources_test src/test/*.cpp)
file(GLOB_RECURSE data resources/*)
# you can use set(sources src/main.cpp) etc if you don't want to
# use globbing to find files automatically


###############################################################################
## target definitions #########################################################
###############################################################################


# add the data to the target, so it becomes visible in some IDE
add_executable(example ${sources} ${data})


# just for example add some compiler flags
target_compile_options(example PUBLIC -std=c++1y -Wall -Wfloat-conversion)


# this lets me include files relative to the root source directory with a <> pair
target_include_directories(example PUBLIC src/main)


# this copies all resource files in the build directory
# we need this, because we want to work with paths relative to the executable
file(COPY ${data} DESTINATION resources)


###############################################################################
## dependencies ###############################################################
###############################################################################


# this defines the variables Boost_LIBRARIES that contain all library names
# that we need to link to
find_package(Boost 1.36.0 COMPONENTS filesystem system REQUIRED)


target_link_libraries(example PUBLIC
${Boost_LIBRARIES}
# here you can add any library dependencies
)


###############################################################################
## testing ####################################################################
###############################################################################


# this is for our testing framework
# we don't add REQUIRED because it's just for testing
find_package(GTest)


if(GTEST_FOUND)
add_executable(unit_tests ${sources_test} ${sources})


# we add this define to prevent collision with the main
# this might be better solved by not adding the source with the main to the
# testing target
target_compile_definitions(unit_tests PUBLIC UNIT_TESTS)


# this allows us to use our executable as a link library
# therefore we can inherit all compiler options and library dependencies
set_target_properties(example PROPERTIES ENABLE_EXPORTS on)


target_link_libraries(unit_tests PUBLIC
${GTEST_BOTH_LIBRARIES}
example
)


target_include_directories(unit_tests PUBLIC
${GTEST_INCLUDE_DIRS} # doesn't do anything on Linux
)
endif()


###############################################################################
## packaging ##################################################################
###############################################################################


# all install commands get the same destination. this allows us to use paths
# relative to the executable.
install(TARGETS example DESTINATION example_destination)
# this is basically a repeat of the file copy instruction that copies the
# resources in the build directory, but here we tell CMake that we want it
# in the package
install(DIRECTORY resources DESTINATION example_destination)


# now comes everything we need, to create a package
# there are a lot more variables you can set, and some
# you need to set for some package types, but we want to
# be minimal here
set(CPACK_PACKAGE_NAME "MyExample")
set(CPACK_PACKAGE_VERSION "1.0.0")


# we don't want to split our program up into several things
set(CPACK_MONOLITHIC_INSTALL 1)


# This must be last
include(CPack)

注意: 虽然上述使用 file(GLOB)在这里是适当的，其中的问题特别要求技术，以尽量减少编辑的频率，以 CMakeLists.txt文件添加新的源文件，这种技术是不鼓励的 在官方文件中，并在这些专门的问题的答案: # 1，# 2。


提交答案