如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

这是我使用的:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

如果你想要进一步的自动备份到7-Zip档案的想法，我有一个免费/开放的项目，你可以使用或审查的想法:http://wittman.org/ziparcy/

这并不是真的更简短，但可能是一种更灵活的方式(信贷):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

另一种方法(信贷):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @(
Set Month=%%A
Set Day=%%B
Set Year=%%C
)


@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

请注意，我在这里的答案仍然依赖于日期和月份的顺序，由区域设置决定-不知道如何解决这个问题。

看到# EYZ0:

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

如果你更喜欢24小时/军事格式的时间，你可以用这个替换第二个FOR行:

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

C:> .\date.bat
.\ 2008 - 10 - 14 _0642 < / p >

如果你想要日期独立于地区日/月顺序，你可以使用“WMIC os GET LocalDateTime”作为源，因为它是ISO顺序:

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

< p > C: >测试。cmd
本地日期是[2012-06-19 10:23:47.048]

不幸的是，这并不是不受区域设置的影响，但它确实是你想要的。

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

你可以在维基百科上找到令人惊讶的东西。

我用这个(同样不是地区独立的(英国))

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

区域独立的日期时间解析

%DATE%和dir命令的输出格式是区域相关的，因此既不健壮也不智能。date.exe (UnxUtils的一部分)以任何可想象的格式提供任何日期和时间信息。您还可以从任何带有date.exe的文件中提取日期/时间信息。

示例:(在cmd脚本中使用%%而不是%)

引用文件中的日期/时间信息 # EYZ0 < / p >

在CMD脚本中使用它来获取年，月，日，时间信息:

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

在CMD脚本中使用它来获得所需格式的时间戳:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

从任何引用文件中提取日期/时间信息。

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

向文件中添加日期/时间信息:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe为免费GNU工具的一部分，无需安装。

注意:将date.exe复制到搜索路径中的任何目录中可能会导致其他使用Windows内置的date命令的脚本失败。

简单回答:

 :: Start - Run , type:
cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"


:: click into target media, Ctrl + V to paste the result

长回答

    @echo off
:: START USAGE  ==================================================================
::SET THE NICETIME
:: SET NICETIME=BOO
:: CALL GetNiceTime.cmd


:: ECHO NICETIME IS %NICETIME%


:: echo nice time is %NICETIME%
:: END USAGE  ==================================================================


echo set hhmmsss
:: this is Regional settings dependant so tweak this according your current settings
for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c
::DEBUG ECHO hhmmsss IS %hhmmsss%
::DEBUG PAUSE
echo %yyyymmdd%
:: this is Regional settings dependant so tweak this according your current settings
for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
::DEBUG ECHO yyyymmdd IS %yyyymmdd%
::DEBUG PAUSE




set NICETIME=%yyyymmdd%_%hhmmsss%
::DEBUG echo THE NICETIME IS %NICETIME%


::DEBUG PAUSE

下面是alt.msdos.batch.nt的一个变体，它独立于本地工作。

把它放在一个文本文件中，例如getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
:: Works on any NT/2k machine independent of regional date settings
@ECHO off
SETLOCAL ENABLEEXTENSIONS
if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
set '%%a'=%%i
set '%%b'=%%j
set '%%c'=%%k))
if %'yy'% LSS 100 set 'yy'=20%'yy'%
set Today=%'yy'%-%'mm'%-%'dd'%
ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%


ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]


:EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

为了让代码在没有错误msg的情况下工作到stderr，我必须在变量赋值%%a， %%b和%%c周围添加单引号。我的locale (PT)在循环/解析的某个阶段导致了错误，比如执行“set =20”之类的东西。引号为赋值语句的左侧生成一个令牌(尽管为空)。

缺点是混乱的区域变量名称:'yy'， 'mm'和'dd'。但是，谁在乎呢!

下面是一种在单行中获取日期时间的方法:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

在美国，这将输出“yyyy-mm-dd hhmm”。不同的区域设置将导致不同的%date%输出，但是您可以修改令牌顺序。

如果需要不同的格式，可以通过重新排列令牌或使用不同(或不使用)分隔符来修改echo语句。

http://sourceforge.net/projects/unxutils/files/

查看ZIP文件中的“Date.exe”，并将其重命名为“DateFormat.exe”(以避免冲突)。

把它放在你的Windows system32文件夹中。

它有很多“日期输出”选项。

请使用DateFormat.exe --h进行帮助

我不确定如何将其输出放入环境变量中…使用设置。

我用批处理文件从vMax更改了这个问题的答案，所以它也适用于荷兰语 荷兰人——像我们一样坚持——在%date%、date/t和date中有一些改变，破坏了原始的批处理文件 如果有些人也能检查其他Windows locale，并报告结果，那就太好了 如果批处理文件在您的位置失败，那么请在命令提示符上包含这两个语句的输出:
# EYZ0 < br > # EYZ0 < / p >

这是你应该从批处理文件中得到的输出示例:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

以下是修改后的代码及其原因:

:: https://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by jeroen@pluimers.com for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
set v_day=
set v_month=
set v_year=


SETLOCAL ENABLEEXTENSIONS
if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
if "%%a" GEQ "A" (
for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
set '%%a'=%%i
set '%%b'=%%j
set 'yy'=%%k
)
)
)
if %'yy'% LSS 100 set 'yy'=20%'yy'%
set Today=%'yy'%-%'mm'%-%'dd'%


ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%


ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
set datestring=%V_Year%%V_Month%%V_Day%
echo %datestring%


:EOF

——基珀斯

这是时间部分的类似批处理文件。

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
@ECHO off
SETLOCAL ENABLEEXTENSIONS
for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
set 'hh'=%%i
set 'mm'=%%j
set 'ss'=%%k
set 'ff'=%%l)
ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%


ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
echo %timestring%


:EOF

——基珀斯

我也遇到过类似的问题。我每天都会从FTP服务器上自动下载一个加密文件。我想使用gpg解密文件，将文件重命名为当前日期(YYYYMMDD格式)，并将解密文件放入正确部门的文件夹中。

我根据日期查看了几个重命名文件的建议，直到我偶然发现了这个简单的解决方案。

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

它工作得很好(例如，文件名显示为“2011-06-14.txt”)。

(来源)

请使用以下脚本在命令行中获取当前日期:

echo %Date:~0,3%day

生成ISO日期格式的区域独立解决方案:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

还可以优化的地方: 如果在修改日期格式的短时间内使用日期格式，其他进程可能会感到困惑。因此，根据现有的格式字符串解析输出可能会“更安全”-但会更复杂

Matthew Johnson的一行解决方案来获取一行程序的日期和时间是有说服力的，这很有用。

然而，它需要一个简单的修改来从批处理文件中工作:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

另外两种不依赖于时间设置的方法(都来自:如何获得独立于本地化的数据/时间:)。它们都可以获得星期几，而且都不需要管理权限!：

1. MAKECAB -将工作在每个Windows系统(快速，但创建一个小的临时文件)(foxidrive脚本):

   @echo off
   pushd "%temp%"
   makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
   for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
   set "current-date=%%e-%%b-%%c"
   set "current-time=%%d"
   set "weekday=%%a"
   )
   del ~.*
   popd
   echo %weekday% %current-date% %current-time%
   pause
   

   # EYZ0。< / p >

2. ROBOCOPY -这不是Windows XP和Windows Server 2003的本机命令，但可以是从微软网站下载。但在windows和Vista及以上版本的所有软件中都是内置的:

   @echo off
   setlocal
   for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
   set "dow=%%D"
   set "month=%%E"
   set "day=%%F"
   set "HH=%%G"
   set "MM=%%H"
   set "SS=%%I"
   set "year=%%J"
   )
   
   
   echo Day of the week: %dow%
   echo Day of the month : %day%
   echo Month : %month%
   echo hour : %HH%
   echo minutes : %MM%
   echo seconds : %SS%
   echo year : %year%
   endlocal
   

   还有三种使用其他Windows脚本语言的方法。它们会给你更多的灵活性，例如，你可以得到一年中的星期，时间以毫秒为单位等等

3. JScript /批处理 hybrid(需要保存为.bat)。作为Windows脚本主机 (虽然可以通过注册表禁用，但这是一个罕见的情况)的一部分，JScript可以在NT及以上的所有系统形式上使用:

   @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment
   
   
   @echo off
   cscript //E:JScript //nologo "%~f0"
   exit /b 0
   *------------------------------------------------------------------------------*/
   
   
   function GetCurrentDate() {
   // Today date time which will used to set as default date.
   var todayDate = new Date();
   todayDate = todayDate.getFullYear() + "-" +
   ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
   ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
   ("0" + todayDate.getMinutes()).slice(-2);
   
   
   return todayDate;
   }
   
   
   WScript.Echo(GetCurrentDate());
   

4. VSCRIPT/BATCH hybrid (Is it possible to embed and execute VBScript within a batch file without using a temporary file?) same case as JScript, but hybridization is not so perfect:

   :sub echo(str) :end sub
   echo off
   '>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
   '& echo current date:
   '& cscript /nologo /E:vbscript "%~f0"
   '& exit /b
   
   
   '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
   '1 = vbLongDate - Returns date: weekday, monthname, year
   '2 = vbShortDate - Returns date: mm/dd/yy
   '3 = vbLongTime - Returns time: hh:mm:ss PM/AM
   '4 = vbShortTime - Return time: hh:mm
   
   
   WScript.echo  Replace(FormatDateTime(Date,1),", ","-")
   

5. PowerShell - can be installed on every machine that has .NET - download from Microsoft (v1, v2, v3 (only for Windows 7 and above)). It is installed by default on everything from Windows 7/Windows Server 2008 and above:

   C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
   

   从批处理文件中使用它:

   for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
   

6. Self-compiled jscript.net/batch (never seen a Windows machine without .NET, so I think this is a pretty portable):

   @if (@X)==(@Y) @end /****** silent line that start JScript comment ******
   
   
   @echo off
   ::::::::::::::::::::::::::::::::::::
   :::       Compile the script    ::::
   ::::::::::::::::::::::::::::::::::::
   setlocal
   if exist "%~n0.exe" goto :skip_compilation
   
   
   set "frm=%SystemRoot%\Microsoft.NET\Framework\"
   
   
   :: Searching the latest installed .NET framework
   for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
   if exist "%%v\jsc.exe" (
   rem :: the javascript.net compiler
   set "jsc=%%~dpsnfxv\jsc.exe"
   goto :break_loop
   )
   )
   echo jsc.exe not found && exit /b 0
   :break_loop
   
   
   
   
   call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
   ::::::::::::::::::::::::::::::::::::
   :::       End of compilation    ::::
   ::::::::::::::::::::::::::::::::::::
   :skip_compilation
   
   
   "%~n0.exe"
   
   
   exit /b 0
   
   
   
   
   ****** End of JScript comment ******/
   import System;
   import System.IO;
   
   
   var dt=DateTime.Now;
   Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));
   

7. Logman This cannot get the year and day of the week. It's comparatively slow and also creates a temporary file and is based on the time stamps that logman puts on its log files. It will work on everything from Windows XP and above. It probably will be never used by anybody - including me - but is one more way...

   @echo off
   setlocal
   del /q /f %temp%\timestampfile_*
   
   
   Logman.exe stop ts-CPU 1>nul 2>&1
   Logman.exe delete ts-CPU 1>nul 2>&1
   
   
   Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
   Logman.exe start ts-CPU 1>nul 2>&1
   
   
   Logman.exe stop ts-CPU >nul 2>&1
   Logman.exe delete ts-CPU >nul 2>&1
   for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t
   
   
   echo %timestamp%
   echo MM: %timestamp:~0,2%
   echo dd: %timestamp:~2,2%
   echo hh: %timestamp:~4,2%
   echo mm: %timestamp:~6,2%
   
   
   endlocal
   exit /b 0
   

8. One more way with WMIC which also gives week of the year and the day of the week, but not the milliseconds (for milliseconds check foxidrive's answer):

   for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
   echo %day%
   echo %DayOfWeek%
   echo %hour%
   echo %minute%
   echo %month%
   echo %quarter%
   echo %second%
   echo %weekinmonth%
   echo %year%
   

9. Using TYPEPERF with some efforts to be fast and compatible with different language settings and as fast as possible:

   @echo off
   setlocal
   
   
   :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
   ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")
   
   
   for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
   set "mon="
   for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
   if not defined mon (
   for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
   set mon=%%a
   set date=%%b
   set year=%%c
   set hour=%%d
   set minute=%%e
   set sec=%%f
   set ms=%%g
   )
   )
   )
   echo %year%.%mon%.%date%
   echo %hour%:%minute%:%sec%.%ms%
   endlocal
   

10. MSHTA allows calling JavaScript methods similar to the JScript method demonstrated in #3 above. Bear in mind that JavaScript's Date object properties involving month values are numbered from 0 to 11, not 1 to 12. So a value of 9 means October.

    <!-- : Batch portion
    
    
    @echo off
    setlocal
    
    
    for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"
    
    
    rem Display all variables beginning with "now."
    set now.
    
    
    goto :EOF
    
    
    end batch / begin HTA -->
    
    
    <script>
    resizeTo(0,0)
    var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
    now = new Date(),
    props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
    'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
    'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
    'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
    'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
    output = [];
    
    
    for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
    close(fso.Write(output.join('\n')));
    </script>
    

一个基于wmic的函数:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
setlocal
for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
endlocal & (
if "%~1" neq "" set %~1=%T:~0,4%
if "%~2" neq "" set %~2=%T:~4,2%
if "%~3" neq "" set %~3=%T:~6,2%
if "%~4" neq "" set %~4=%T:~8,2%
if "%~5" neq "" set %~5=%T:~10,2%
if "%~6" neq "" set %~6=%T:~12,2%
)
goto:eof

好处:地区独立。只有系统管理员才能运行wmic.exe。

用法:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

它像这样回显一个字符串:

2014-01-22 12:51:53

注意，函数形参是外形参——也就是说，您必须提供变量名而不是值。

所有参数都是可选的，因此如果您只想获取年和月，那么call:Now Y M是一个有效的调用。

这段代码的前四行将为您提供可靠的YY DD MM YYYY HH Min Sec变量，适用于Windows XP Professional及更高版本。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"


set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

就用这句话:

PowerShell -Command "get-date"

给定一个已知位置，供函数形式参考。ECHOTIMESTAMP调用显示了如何将时间戳转换为变量(本例中为DTS)。

@ECHO off


CALL :ECHOTIMESTAMP
GOTO END


:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF


:ECHOTIMESTAMP
SETLOCAL
CALL :TIMESTAMP DTS
ECHO %DTS%
ENDLOCAL
GOTO :EOF


:END


EXIT /b 0

并保存到文件，timestamp.bat，下面是输出:

我知道已经提到了很多方法。但下面是我的方法来分解它，以了解它是如何做到的。希望对喜欢循序渐进法的人有所帮助。

:: Check your local date format
echo %date%


:: Output is Mon 08/15/2016


:: get day (start index, number of characters)
::         (index starts with zero)
set myday=%DATE:~0,4%
echo %myday%
:: output is Mon


:: get month
set mymonth=%DATE:~4,2%
echo %mymonth%
:: output is 08


:: get date
set mydate=%DATE:~7,2%
echo %mydate%
:: output is 15


:: get year
set myyear=%DATE:~10,4%
echo %myyear%
:: output is 2016

在Windows 7中，这段代码适用于我:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%


SET DATE_FRM=%YEAR%-%MONTH%-%DAY%
ECHO %DATE_FRM%

:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 adolfo.dimare@gmail.com
:: - http://stackoverflow.com/questions/203090
@echo off


set _isotime=
set _now=


:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_


if not (%1)==() goto _help
SetLocal EnableDelayedExpansion


:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
IF "%%~L"=="" goto  _WMIC_done_
set _yyyy=%%L
set _mm=00%%J
set _dd=00%%G
set _hour=00%%H
set _minute=00%%I
set _second=00%%K
)
:_WMIC_done_


::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017


:: Remove excess leading zeroes
set _mm=%_mm:~-2%
set _dd=%_dd:~-2%
set _hour=%_hour:~-2%
set _minute=%_minute:~-2%
set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%


:: Set date/time in ISO 8601 format:
Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format


if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
set /a _hour=1%_hour%-12
set _hour=%_hour:~-2%
set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
:: -> https://ss64.com/nt/if.html
:: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
:: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_


EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out


:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"


:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.


:_out
:: EOF: GetDate.cmd

我注意到o/p确实不要求一个与区域无关的解决方案。不过，我的解决方案是针对英国的。

这是在批处理文件中使用的最简单的解决方案，一行解决方案:

FOR /F "tokens=1-3 delims=/" %%A IN ("%date%") DO (SET today=%%C-%%B-%%A)
echo %today%

可以通过改变输出语句中变量%%A %%B和%%C的顺序来改变该解决方案，以提供所需的任何日期格式(例如YY-MM-DD或DD-MM-YY)。

我的意图-我的只有意图-在发布这个答案是为了证明这可以在命令行上完成，通过使用单行代码来实现它。

而且，像其他人那样发布运行35行代码的答案是多余的，因为o/p在问题中特别要求命令行解决方案。因此，o/p专门寻求单线解决方案。

将Powershell合并到一个批处理文件中，并使用元变量为每个文件赋值:

@echo off
for /f "tokens=1-6 delims=-" %%a in ('PowerShell -Command "& {Get-Date -format "yyyy-MM-dd-HH-mm-ss"}"') do (
echo year: %%a
echo month: %%b
echo day: %%c
echo hour: %%d
echo minute: %%e
echo second: %%f
)

如果您更喜欢月份名称MMM或MMMM, 12小时到24小时格式hh或HH，您也可以更改格式

• 我使用date.exe，并将其重命名为date_unxutils.exe以避免冲突。

• 把它放在批处理脚本旁边的bin文件夹中。

代码

:: Add binaries to temp path
IF EXIST bin SET PATH=%PATH%;bin


:: Create UTC Timestamp string in a custom format
:: Example: 20210128172058
set timestamp_command='date_unxutils.exe -u +"%%Y%%m%%d%%H%%M%%S"'
FOR /F %%i IN (%timestamp_command%) DO set timestamp=%%i
echo %timestamp%

下载UnxUtils

• # EYZ0。

参考文献

• 这是我基于太棒了的回答。

[int] $day = Get-Date -UFormat %d
[int] $month = Get-Date -UFormat %m
[int] $year = Get-Date -UFormat %y
[String] $date = "$($day)$($month)$($year)"
$time = Get-Date -UFormat %R
$time -replace ‘[:]’,”"
$fileFolderName = $date + time