如何使用windows批处理文件循环文本文件中的每一行?

如果你有NT-family Windows(一个使用cmd.exe作为shell的Windows)，尝试FOR /F命令。

从Windows命令行引用:

要解析一个文件，忽略注释行，输入:

for /F "eol=; tokens=2,3* delims=," %i in (myfile.txt) do @echo %i %j %k

这个命令解析Myfile.txt中的每一行，忽略以分号开头的行，并将每行的第二和第三个标记传递给FOR主体(标记由逗号或空格分隔)。FOR语句体引用%i来获取第二个令牌，引用%j来获取第三个令牌，引用%k来获取所有剩余的令牌。

如果您提供的文件名包含空格，则在文本周围使用引号(例如，“文件名”)。要使用引号，必须使用usebackq。否则，引号将被解释为定义要解析的字面值字符串。

顺便说一下，你可以在大多数Windows系统上找到命令行帮助文件:

 "C:\WINDOWS\Help\ntcmds.chm"

这是我写的一个bat文件来执行文件夹中的所有SQL脚本:

REM ******************************************************************
REM Runs all *.sql scripts sorted by filename in the current folder.
REM To use integrated auth change -U <user> -P <password> to -E
REM ******************************************************************


dir /B /O:n *.sql > RunSqlScripts.tmp
for /F %%A in (RunSqlScripts.tmp) do osql -S (local) -d DEFAULT_DATABASE_NAME -U USERNAME_GOES_HERE -P PASSWORD_GOES_HERE -i %%A
del RunSqlScripts.tmp

我需要把整条线作为一个整体来处理。以下是我发现有效的方法。

for /F "tokens=*" %%A in (myfile.txt) do [process] %%A

带有星号(*)的tokens关键字将提取整行的所有文本。如果你不加星号，它只会拉出一行中的第一个单词。我想这和空格有关。

For Command on TechNet .

如果文件路径中有空格，则需要使用usebackq。为例。

for /F "usebackq tokens=*" %%A in ("my file.txt") do [process] %%A

或者，你可以排除引号中的选项:

FOR /F %%i IN (myfile.txt) DO ECHO %%i

在批处理文件中，必须使用%%而不是%:(类型help for)

for /F "tokens=1,2,3" %%i in (myfile.txt) do call :process %%i %%j %%k
goto thenextstep
:process
set VAR1=%1
set VAR2=%2
set VAR3=%3
COMMANDS TO PROCESS INFORMATION
goto :EOF

当您在批处理程序中使用for命令时，您需要为变量使用双%符号。

下面几行将这些变量从for命令传递给进程“子例程”，并允许您处理这些信息。

set VAR1=%1
set VAR2=%2
set VAR3=%3

我有一些非常高级的使用这个确切的设置，如果需要更多的例子，我愿意分享。当然，根据需要添加您的EOL或Delims。

改进第一个“FOR /F..”答案: 我要做的是调用执行MyList.txt中列出的每个脚本，所以它为我工作:

for /F "tokens=*" %A in  (MyList.txt) do CALL %A ARG1

——或者，如果你想在多行上做:

for /F "tokens=*" %A in  (MuList.txt) do (
ECHO Processing %A....
CALL %A ARG1
)

编辑:上面给出的例子是从命令提示符执行for循环;在批处理脚本中，需要添加一个额外的%，如下所示:

---START of MyScript.bat---
@echo off
for /F "tokens=*" %%A in  ( MyList.TXT) do  (
ECHO Processing %%A....
CALL %%A ARG1
)
@echo on
;---END of MyScript.bat---

修改示例在这里列出我们的Rails应用程序在Heroku -谢谢!

cmd /C "heroku list > heroku_apps.txt"
find /v "=" heroku_apps.txt | find /v ".TXT" | findstr /r /v /c:"^$" > heroku_apps_list.txt
for /F "tokens=1" %%i in (heroku_apps_list.txt) do heroku run bundle show rails --app %%i

完整代码在这里。

@MrKraus的回答很有启发性。此外，让我添加如果您想加载位于同一目录中的文件作为批处理文件，文件名前缀为%~dp0。这里有一个例子:

cd /d %~dp0
for /F "tokens=*" %%A in (myfile.txt) do [process] %%A

注::如果你的文件名或目录(例如上面例子中的myfile.txt)有一个空格(例如:'my file.txt'或'c:\程序文件')，使用:

for /F "tokens=*" %%A in ('type "my file.txt"') do [process] %%A

，使用类型关键字调用type程序，该程序显示文本文件的内容。如果您不想承受调用type命令的开销，您应该将目录更改为文本文件的目录。注意，带空格的文件名仍然需要type。

我希望这能帮助到一些人!

接受的答案是好的，但有两个限制 它删除空行和以;

要读取任何内容的行，您需要延迟展开切换技术。

@echo off
SETLOCAL DisableDelayedExpansion
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ text.txt"`) do (
set "var=%%a"
SETLOCAL EnableDelayedExpansion
set "var=!var:*:=!"
echo(!var!
ENDLOCAL
)

Findstr用于用行号和冒号作为每行的前缀，因此空行不再是空的。

在访问%%a参数时，需要禁用delayeexpand，否则感叹号!和插入号^将丢失，因为它们在该模式中具有特殊含义。

但是如果要从该行中删除行号，需要启用延迟扩展 set "var=!var:*:=!"将删除第一个冒号之前的所有冒号(使用delims=:还将删除一行开头的所有冒号，而不仅仅是findstr中的冒号)

唯一的限制现在是线长限制~8191，但似乎没有办法克服这一点。

使用cmd.exe和

for /F "tokens=*" %F in (file.txt) do whatever "%F" ...

仅适用于“正常”文件。对于巨大的文件，它失败得很惨。

对于大文件，你可能需要使用Powershell和类似的东西:

[IO.File]::ReadLines("file.txt") | ForEach-Object { whatever "$_" }

或者如果你有足够的内存:

foreach($line in [System.IO.File]::ReadLines("file.txt")) { whatever "$line" }

这适用于一个250 MB的文件，包含200多万行，其中for /F ...命令在几千行之后卡住了。

有关foreach和ForEach-Object之间的区别，请参见了解ForEach和ForEach对象。

(字幕:在PowerShell中逐行读取文件)

从命令行打印文本文件中的所有行(使用delayeexpansion):

set input="path/to/file.txt"


for /f "tokens=* delims=[" %i in ('type "%input%" ^| find /v /n ""') do (
set a=%i
set a=!a:*]=]!
echo:!a:~1!)

适用于前导空白、空行、空白行。

在win10 CMD上测试